Check your ip/computername with nslookup in powershell

Nslookup is a great tool for testing and troubleshooting. However, if you need to check a large range of IP/Computername in mass, nslookup is not the better choice. So, this below script could help you to do the same in powershell. (Download script)

#
#  NSLookup
#
#  by F.Richard 2011-05
#


# ***********************************************

Function NSlookup {
 Param($hostname)
 #$iphostEntry = [System.Net.Dns]::GetHostEntry($hostname) 
 # Rexolve obsolete but better than GetHostEntry
 $iphostEntry = [System.Net.Dns]::Resolve($hostname) 
 $line = $iphostEntry.HostName 

 $strSeparator = ";"
 foreach ($addr in $iphostEntry.AddressList) { 
  $line = $line + $strSeparator + $Addr.IPAddressToString 
  $strSeparator = "|"
 }  

 $strSeparator = ";"
 foreach ($alias in $iphostEntry.aliases) { 
  $line = $line + $strSeparator + $alias 
  $strSeparator = "|"
 } 

 return $line
}



# ***********************************************

Function TestFile {
 Param(
 [String] $strFilename,
 [String] $strCurDir
 ) 
 if ($strFilename) {
  $strCurDir = $(if ($strCurDir) {$strCurDir} else {if ($MyInvocation.MyCommand.CommandType -eq "Function") {(Get-Location).Path} else {Split-Path -parent $MyInvocation.MyCommand.Path} })
  If ((Test-Path("$strFilename")) -eq $False){
   If ($strFilename.ToUpper().Contains($strCurDir.ToUpper()) ) {
    Write-Host "ERROR: file $strFilename NOT exist"
    return
   } Else {
    If ((Test-Path("$strCurDir\$strFilename")) -eq $False){
     Write-Host "ERROR: file $strFilename NOT exist"
     Write-Host "ERROR: file $strCurDir\$strFilename NOT exist"
     return
    } Else {
     $strFilename = "$strCurDir\$strFilename"
    }
   }
  }
  return $strFilename
 }
}


# ***********************************************

Function GetFileIntoArr {
 Param(
 [String] $strFilename,
 [String] $strCurDir, 
 [Ref]$arrFile, 
 [String] $strComment
 ) 
 $strComment = $(if ($strComment) {$strComment} else {"#"})
 $strCurDir = $(if ($strCurDir) {$strCurDir} else {if ($MyInvocation.MyCommand.CommandType -eq "Function") {(Get-Location).Path} else {Split-Path -parent $MyInvocation.MyCommand.Path} })
 
 $retFilename = TestFile -strFilename $strFilename -strCurDir $strCurDir
 if ($retFilename) {
  $Content = Get-Content "$retFilename"
  Foreach ($line in $Content) {
   $comment = $False
   If ($line.Trim().length -gt 0) { # take only line with data and without # at begininng of the line
    # if we do not want to use comment 
    If ($strComment -eq "#") {
     If ($line.substring(0,1) -eq "#") {
      $comment = $True
     }   
    }
    If ($comment -eq $False) {
     # Get Search & Replace
     $arrFile.Value += $line.Trim()
    }
   }
  }
  return $True
 } else {
  return $False
 }
}

# ***********************************************

#
# MAIN PROGRAM
#

# Verify Arguments Number
If($Args.Count -lt 2) {
 Write-Host "Syntax:"$MyInvocation.MyCommand.Name "inputfilename outputfilename"
 Write-Host " Example:"$MyInvocation.MyCommand.Name" 'inputfile.txt' 'outputfile.txt' "
 Write-Host " Example:"$MyInvocation.MyCommand.Name" -inputfile 'inputfile.txt' -outputfile 'outputfile.txt' "
 Write-Host 
 Break 
}

$inputfile = $args[0]
$outputfile = $args[1]
$date = get-date -format "yyyy-MM-dd"
$Content = "#Date;Computer;Hostname;IP`r`n"
$Content | Out-File -encoding ASCII $outputfile 
[Array] $arrComputers = @( ) 

if ($inputfile) {
        if (!(GetFileIntoArr -strFilename $inputfile -arrFile ([Ref]$arrComputers))) { 
  Break 
 }
} else {
 Write-Host "ERROR: you need a filename.txt as second parameter inputfile"
 Break 
}
Foreach ($computer in $arrComputers) {
 $nslookup = NSlookup($computer)
 $line = $date + ";" + $computer + ";" + $nslookup 
 #+ "`r`n"
 Write-Host $line
 $line | Out-File -append -encoding ASCII $outputfile 
}    

Example of Result:

#Date;Computer;Hostname;IP
2011-06-01;COMPUTER1;computer1.dns1.my.net;192.1.1.45;COMPUTER1.dns2.my.net
2011-06-01;COMPUTER2;COMPUTER2.si.net;192.1.1.100
2011-06-01;COMPUTER3;COMPUTER3.si.net;192.1.1.101
2011-06-01;COMPUTER4;COMPUTER4.si.net;192.1.102

Get Windows Network configuration Remotely

Today a 1 hour script. We need to know some network informations on a lot of computers, especially DNS search order.

In powershell, that's easy done by using

$strComputername = "localhost"
$NICs = Get-WmiObject Win32_NetworkAdapterConfiguration -Computername $strComputername | Where {$_.IPEnabled -eq "TRUE"}
foreach ($nic in $nics) {
 $nic.DNSServerSearchOrder
}

Unfortunately, for a lot of reason, I can't use powershell. No time to lose. So I use one of my old vbscript and adapt it using information coming from Microsoft Site(Automating TCP/IP Networking on Clients - Part 2: Scripting Basic TCP/IP Networking on Clients)

That's the result that you can download too

'
' Get All Network Configuration
'
'
' F.RICHARD
' 2010 October
'

Option Explicit
Const ForReading = 1, ForWriting = 2, ForAppending = 8 


' Detect WScript or CScript
'
If InStr(LCase(WScript.FullName), "wscript")>0 Then  ' ex: FullName = C:\WINNT\system32\wscript.exe 
 WScript.Echo "This script must be run under CScript."
 WScript.Quit
End If


' Get Path
'
Dim strScriptFullName, strScriptPath, strScriptName
strScriptName = WScript.ScriptName
strScriptFullName = WScript.ScriptFullName ' ex: C:\Program Files\MyFolder\MyProg.exe
strScriptPath = Left(strScriptFullName, InStrRev(strScriptFullName, "\") - 1) ' ex: C:\Program Files\MyFolder


' Variables For File
Dim objFSO
Set objFSO = CreateObject("Scripting.FileSystemObject")


' Input parameter
'
Dim objInputFile, strInputFile
If WScript.Arguments.Named.Exists("input") Then
 strInputFile = WScript.Arguments.Named("input")

 If Not isFileExist(strInputFile) Then
  If Not isFileExist(strScriptPath & "\" & strInputFile) Then
   WScript.Echo strInputFile & " File Not Exist !"
   WScript.Echo strScriptPath & "\" & strInputFile & " File Not Exist !"
   WScript.Quit
  End If
  strInputFile = strScriptPath & "\" & strInputFile
 End If    
 Set objInputFile = objFso.OpenTextFile(strInputFile, ForReading) 
Else
 WScript.Echo "You must defined an argument /input ex: /input:input.txt !"
 WScript.Quit

End If


' Output parameter
Dim strOutputFile, objOutputFile
If WScript.Arguments.Named.Exists("output") Then
 strOutputFile = WScript.Arguments.Named("output")
Else
 WScript.Echo "You must defined an argument /output ex: /input:output.txt !"
 WScript.Quit

End If
On Error Resume Next
Set objOutputFile = objFSO.CreateTextFile(strOutputFile, ForWriting, True)  ' delete file
If (Err.Number <> 0) Then
 WScript.Echo strOutputFile & " file - permission denied or file already opened"
 On Error GoTo 0
 WScript.Quit
End If
On Error GoTo 0




' Put servers in Dictionary
'
Dim objItem, objDictionary, objTextFile, strNextLine, i
Set objDictionary = CreateObject("Scripting.Dictionary")
Set objTextFile = objFSO.OpenTextFile (strInputFile, ForReading)
i = 0
Do Until objTextFile.AtEndOfStream
 strNextLine = Trim(objTextFile.Readline)
 If (Len(strNextLine)>1) Then
  If Not Left(strNextLine, 1) = "#" Then
   objDictionary.Add i, strNextLine
   i = i + 1
  End If
 End If
Loop

Dim line
line = "Hostname;NICDescription;MACAddress;IPAddress;IPSubnet;DefaultIPGateway;DHCPEnabled;DHCPServer;DNSDomain;DNSDomainSuffixSearchOrder;WINSPrimaryServer;WINSSecondaryServer;DNSServerSearchOrder1;DNSServerSearchOrder2"
WScript.Echo line  
objOutputFile.WriteLine(line)

Dim objWMIService, objWMIServiceRemote, colAdapters, objAdapter
Dim strComputerName, computers, objComputer  
Dim DNSHostname, NICDescription, MACAddress, IPAddress, IPSubnet, DefaultIPGateway
Dim DHCPEnabled, DHCPServer, DNSDomain, DNSDomainSuffixSearchOrder, WINSPrimaryServer, WINSSecondaryServer
Dim DNSServerSearchOrder
Set objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\cimv2")
For Each objItem in objDictionary
 strComputerName = objDictionary.Item(objItem)
 WScript.Echo strComputerName  
 Set Computers = objWMIService.ExecQuery ("Select * from Win32_PingStatus Where Address = '" & strComputerName & "'")
 For Each objComputer in Computers
  If objComputer.StatusCode = 0 Then
   ' suppress errors in case of errors
   On Error Resume Next
   Set objWMIServiceRemote = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputerName & "\root\cimv2")

   ' Only query Enabled NIC
   Set colAdapters = objWMIServiceRemote.ExecQuery("SELECT * FROM Win32_NetworkAdapterConfiguration WHERE IPEnabled = True")
   'Wscript.echo Err.Number & ";" & Err.Description

   Select Case Err.number
    'Case "-2147022676" :
    ' line = strComputerName & ";" & strGroupToCheck & " group NOT EXIST"
    ' WScript.Echo line
    ' objOutputFile.WriteLine(line)

    Case "-2147024843" : 
     line = strComputerName & ";INVALID Network Path OR insufficient access rights"
     WScript.Echo line
     objOutputFile.WriteLine(line)

    'Case "-2147463168" :
    ' line = strComputerName &  ";INVALID ADSI WinNT://" & strComputerName & "/" & strGroupToCheck & ",group"
    ' WScript.Echo line
    ' objOutputFile.WriteLine(line)

    Case Else :
     For Each objAdapter in colAdapters
      ' DNS Host name 
      DNSHostname =""
      DNSHostname = objAdapter.DNSHostName


      ' NIC Description
      NICDescription = objAdapter.Description


      ' MAC Address
      MACAddress = ""
      MACAddress = objAdapter.MACAddress
      
      
      ' IP Address
      IPAddress = ""
      If Not IsNull(objAdapter.IPAddress) Then
       For i = 0 To UBound(objAdapter.IPAddress)
        If (IPAddress = "") Then
         IPAddress = objAdapter.IPAddress(i)
        Else
         IPAddress = IPAddress & "_" & objAdapter.IPAddress(i)
        End If
       Next
      End If


      ' IP Subnet 
      IPSubnet = ""
      If Not IsNull(objAdapter.IPSubnet) Then
       For i = 0 To UBound(objAdapter.IPSubnet)
        If (IPSubnet = "") Then 
         IPSubnet = objAdapter.IPSubnet(i)
        Else
         IPSubnet = IPSubnet & "_" & objAdapter.IPSubnet(i)
        End If
       Next
      End If


      ' Default Gateway
      DefaultIPGateway = ""
      If Not IsNull(objAdapter.DefaultIPGateway) Then
       For i = 0 To UBound(objAdapter.DefaultIPGateway)
        If (DefaultIPGateway = "") Then 
         DefaultIPGateway = objAdapter.DefaultIPGateway(i)
        Else
         DefaultIPGateway = DefaultIPGateway  & "_" & objAdapter.DefaultIPGateway(i)
        End If
       Next
      End If


      ' DHCP Enabled
      DHCPEnabled = ""
      DHCPEnabled = objAdapter.DHCPEnabled


      ' DHCP server
      DHCPServer = ""
      DHCPServer = objAdapter.DHCPServer


      ' DNS Domain
      DNSDomain = objAdapter.DNSDomain


      ' DNS Domain Suffix Search Order
      DNSDomainSuffixSearchOrder = ""
      If Not IsNull(objAdapter.DNSDomainSuffixSearchOrder) Then
       For i = 0 To UBound(objAdapter.DNSDomainSuffixSearchOrder)
        If (DNSDomainSuffixSearchOrder = "") Then 
         DNSDomainSuffixSearchOrder = objAdapter.DNSDomainSuffixSearchOrder(i)
        Else
         DNSDomainSuffixSearchOrder = DNSDomainSuffixSearchOrder   & "_" & objAdapter.DNSDomainSuffixSearchOrder(i)
        End If
       Next
      End If

      WINSPrimaryServer = objAdapter.WINSPrimaryServer
      WINSSecondaryServer = objAdapter.WINSSecondaryServer

      ' DNS Search Order 
      DNSServerSearchOrder = ""
      If Not IsNull(objAdapter.DNSServerSearchOrder) Then
       For i = 0 To UBound(objAdapter.DNSServerSearchOrder)
        DNSServerSearchOrder = DNSServerSearchOrder & ";" & objAdapter.DNSServerSearchOrder(i)
       Next
      End If


      line = DNSHostname & ";" & NICDescription & ";" & MACAddress & ";" & IPAddress & ";" & IPSubnet & ";" & DefaultIPGateway & ";" & DHCPEnabled & ";" & DHCPServer & ";" & DNSDomain & ";" & DNSDomainSuffixSearchOrder & ";" & WINSPrimaryServer & ";" & WINSSecondaryServer &  DNSServerSearchOrder
      WScript.Echo line  
      objOutputFile.WriteLine(line)
     Next
 
   End Select
   On Error Goto 0
  Else
   line = strComputerName & ";NOT available"
   WScript.Echo  line
   objOutputFile.WriteLine(line)
  End If
 Next
Next


'--------------------


' Help
'
' Help File
'

Sub Help(ByRef strScriptName)
 WScript.Echo strScriptName & " Arguments" & vbCrLf _ 
  & vbTab & "/input:""filename_for_server_list""" & vbCrLf _
  & vbTab & "/output:""filename_for_output""" & vbCrLf _
  & vbTab & "/? or nothing for this" & vbCrLf _
      & vbCrLf & "Example:" & vbCrLf _
      & "cscript " & strScriptName & " /input:""servers.txt"" /input:""result.csv"" " & vbCrLf
 WScript.Quit(0)
End Sub


'--------------------

' isFileExist
'
' Test if File Exist
'
Function IsFileExist(ByRef strInputFile)
 Dim iReturn
 iReturn = False

 Dim objFSO
 On Error Resume Next
 Set objFSO = CreateObject("Scripting.FileSystemObject")
 If objFSO.FileExists(strInputFile) Then
  iReturn = True 
 End If
 Set objFSO = Nothing
 On Error Goto 0

 IsFileExist = iReturn
End Function


'--------------------

' pingComputer
'
' Ping Test
'
Function pingComputer(strComputerName)

 Dim pingStatus, objPing, objStatus
 pingStatus = false
 Set objPing = GetObject("winmgmts:{impersonationLevel=impersonate}")
 Set objPing = objPing.ExecQuery("select * from Win32_PingStatus where address = '" & strComputerName & "'")
 For Each objStatus in objPing
  If IsNull(objStatus.StatusCode) or objStatus.StatusCode<>0 Then 
   pingComputer = false
  Else
   pingComputer = true
  End If
 Next


End Function

'--------------------